환경

Unity5.5

DOTween

드라쿠에 여행의 문이라든지, 마더의 전투 장면이라든지 화면의 왜곡을 표현하는데 사용되는 것 같다.
어딘가의 기사에서 읽었습니다만, 패미콘 세대의 레이스 게임으로 코너를 표현하는데도 사용되고 있었다든가 없다든가.
선인의 지혜는 훌륭합니다.



Shader측의 Property에는

speed : 주기 속도

amplitude : 흔들림의 강도 (진폭)

을 정의합니다.

Y축의 1라인(dot?)마다 x를 스크롤시킵니다.
다만 모든 Y축의 라인마다 x를 스크롤 시키는 것만으로는, 텍스처가 옆으로 어긋나 갈 뿐이므로
Sin파를 이용하여 서서히 어긋나갑니다.

Shader측

RasterScroll.shader

Shader "Custom/RasterScroll"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _speed("speed", float) = 0.2
        _amplitude("amplitude", float) = 1.0
    }
    SubShader
    {
        // No culling or depth
        Cull Off ZWrite Off ZTest Always

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                return o;
            }

            sampler2D _MainTex;
            float _speed;
            float _amplitude;
            float _frequency;

            fixed4 frag (v2f i) : SV_Target
            {
                // 時間の取得
                float time = _Time.y * _speed;

                // y軸ライン上のx座標をずらす
                float dx = _amplitude * sin(radians((i.uv.y + time) * 360));

                // x成分をスクロールさせる
                i.uv.x += dx;

                return tex2D(_MainTex, i.uv);
            }
            ENDCG
        }
    }
}

스크립트측

RasterScroll.cs

using System.Collections;
using System.Collections.Generic;
using UnityEngine;

[ExecuteInEditMode]
public class RasterScroll : MonoBehaviour {
    private Material material;

    /// <summary>
    /// 時間の進みの速さ
    /// </summary>
    [SerializeField, Header("周期"), Range(0.0f, 2.0f)]
    private float speed;

    /// <summary>
    /// 振幅
    /// </summary>
    [SerializeField, Header("振幅"), Range(0.0f, 2.0f)]
    private float amplitude;

    void Start ()
    {
        material = new Material (Shader.Find ("Custom/RasterScroll"));
    }

    void OnRenderImage (RenderTexture source, RenderTexture destination)
    {
        UpdateMaterial ();
        Graphics.Blit (source, destination, material);
    }

    void UpdateMaterial ()
    {
        material.SetFloat ("_speed", speed);
        material.SetFloat ("_amplitude", amplitude);
    }
}