Fisheye shader

플라네타륨 영상을 작성＆상영할 기회가 있어, 몇 가지 만들어 상영해 왔습니다.

플라네타륨 영상을 Unity로





샘플 영화 을 몇개 만들어 시험한 결과, cubemap을 사용한 360영상 가 아니어도, FoV90[deg] 정도의 카메라로 FishEye(어안 렌즈)화한 것도 적당할 것 같은 느낌이었으므로, Fisheye 쉐이더를 준비합니다 했다.

FisheyeShader.shader

Shader "Unlit/FisheyeShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Rate ("Distortion Rate", Range(0.55,0.7)) = 0.58
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
//      Cull Off ZWrite Off ZTest Always

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #pragma multi_compile _ IS_SQUARE
            #pragma multi_compile _ USE_MASK

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
                float rate : RATE;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float _Rate;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                #ifndef IS_SQUARE
                    o.rate = 1;
                #else
                    o.rate = _ScreenParams.x/_ScreenParams.y;
                #endif
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                float2 coord = (i.uv-0.5);
                float dist = (distance(coord, 0));
                #ifdef USE_MASK
                #ifndef IS_SQUARE
                if(dist>0.5){ return fixed4(0,0,0,0);}
                #else
                float2 ckCoord = (0.5 - i.uv)*float2(i.rate,1);
                float ckDist = (distance(ckCoord, 0));
                if(ckDist>0.5){ return fixed4(0,0,0,0);}
                #endif
                #endif

                float ang = atan2(coord.y,coord.x);
                float r = tan(dist * UNITY_PI/2) / tan(_Rate * UNITY_PI);
                coord.x = cos(ang)*r*2;
                coord.y = sin(ang)*r*2;
                coord = max(min(0.5-coord,1),0);
                fixed4 col = tex2D(_MainTex, coord);
                return col;
            }
            ENDCG
        }
    }
}

카메라에 적용하는 것은 카메라에 연결된 스크립트 내에서

void OnRenderImage(RenderTexture src, RenderTexture dest){
  Graphics.Blit(src, dest, material);
}

같아요.

원본 이미지


피쉬 아이


360화상(dome master)