SGplot 그림 예제
*Grouping a Scatter Plot;
proc sgplot data=sashelp.class;
scatter x=height y=weight / group=sex;
run;
*Plotting Three Series;
proc sgplot data=sashelp.stocks
(where=(date >= "01jan2000"d and stock = "IBM"));
title "Stock Trend";
series x=date y=close;
series x=date y=low;
series x=date y=high;
run;
*Adding Prediction and Confidence Bands to a Regression Plot;
proc sgplot data=sashelp.class;
reg x=height y=weight / CLM CLI;
run;
*Adding a Prediction Ellipse to a Scatter Plot;
proc sgplot data=sashelp.iris;
title "Iris Petal Dimensions";
scatter x=petallength y=petalwidth;
ellipse x=petallength y=petalwidth;
keylegend / location=inside position=bottomright;
run;
*Creating Lines and Bands from Pre-Computed Data;
proc sgplot data=sashelp.classfit;
title "Fit and Confidence Band from Precomputed Data";
band x=height lower=lower upper=upper /
legendlabel="95% CLI" name="band1";
band x=height lower=lowermean upper=uppermean /
fillattrs=GraphConfidence2
legendlabel="95% CLM" name="band2";
scatter x=height y=weight;
series x=height y=predict / lineattrs=GraphPrediction
legendlabel="Predicted Fit" name="series";
keylegend "series" "band1" "band2" / location=inside position=bottomright;
run;
*Adding Statistical Limits to a Dot Plot;
proc sgplot data=sashelp.class(where=(age<16));
dot age / response=height stat=mean
limitstat=stddev numstd=1;
run;
*Combining Histograms with Density Plots;
proc sgplot data=sashelp.heart;
title "Cholesterol Distribution";
histogram cholesterol;
density cholesterol;
density cholesterol / type=kernel;
keylegend / location=inside position=topright;
run;
*Creating a Horizontal Box Plot;
proc sgplot data=sashelp.heart;
title "Cholesterol Distribution by Weight Class";
hbox cholesterol / category=weight_status;
run;
*Creating a Bar-Line Chart;
proc sgplot data=sashelp.stocks (where=(date >= "01jan2000"d
and date <= "01jan2001"d
and stock = "IBM"));
title "Stock Volume vs. Close";
vbar date / response=volume;
vline date / response=close y2axis;
run;
이 내용에 흥미가 있습니까?
현재 기사가 여러분의 문제를 해결하지 못하는 경우 AI 엔진은 머신러닝 분석(스마트 모델이 방금 만들어져 부정확한 경우가 있을 수 있음)을 통해 가장 유사한 기사를 추천합니다:
JS_3. 내장객체Math는 전역객체이기 때문에 new 키워드 사용하지 않음 new Object() 대신 { } 사용가능 new Array() 대신 [ ] 사용가능 new String()대신 " " 사용가능 new Boolean()대...
텍스트를 자유롭게 공유하거나 복사할 수 있습니다.하지만 이 문서의 URL은 참조 URL로 남겨 두십시오.
CC BY-SA 2.5, CC BY-SA 3.0 및 CC BY-SA 4.0에 따라 라이센스가 부여됩니다.