FlashAir의 컨트롤 이미지 상태 바꾸기(UWSC)

미리 준비하다
Flash Air라는 SD 카드를 아십니까?
SD카드에는 무선 LAN이 내장돼 있어 스마트폰과 컴퓨터를 통해 카메라로 찍은 사진에 직접 접근할 수 있어 편리하다.
같은 기능을 제공하는 아이피카드와 달리 단순한 와이파이 기능과 전용 클라이언트만 제공하기 때문에 비교적 간단하게 사용하는 것이 특징이다(Eye-Fi라면 잘 사용해도 쉽게 사용할 수 있다).
그렇다면 이 플래시 에어는 PC의 SD 카드로도 의외로 사용할 수 있다.SD카드를 PC에 연결하면 SD카드의 무선 LAN이 켜져 내부에 있는 파일을 외부에서 접근할 수 있어 간단한 공개 폴더로 활용할 수 있다.
컴퓨터에서 Flash Air 사용
그러면 이 Flash Air는 무선 LAN 부팅 모드가 있습니다.
초기에 설정된 자동 부팅 모드에서는 장치의 전원을 켜거나 SD 카드를 꽂은 후 5분 후에 무선 LAN이 시작됩니다.하지만 컴퓨터는 켜기 = 컴퓨터의 시동이 걸려서 잘 안 돼요.
'수동 부팅 모드'의 경우 SD카드에 처음 들어간 제어 이미지의 보호 설정(PC의 경우 읽기 전용 설정에 해당)은 무선 LAN의 부팅 스위치(읽기 전용 ON: 무선 LANOFF, 읽기 전용 OFF: 무선 LANON)이다.그러나 Windows의 경우 읽기 전용 설정을 전환하려면 컨트롤 이미지의 속성을 열어 체크 상자를 조작해야 하기 때문에 매우 번거롭다.
제어 이미지 읽기 스크립트 만들기
오프닝이 길어졌다.한 마디로 하면 컨트롤 이미지를 전환하는 읽기 전용 스크립트를 쓸 수 있습니다.따라서 UWSC를 사용하여 제어 스크립트를 써 보았습니다.
FlashAirStateChanger.uws

dim fso = CREATEOLEOBJ("Scripting.FileSystemObject")
for i = 0 to GETOLEITEM(fso.Drives) - 1
  // ドライブの検索(リムーバブルかつ、制御用画像が存在するか？)
  dim d = ALL_OLE_ITEM[i]
  PRINT d.DriveLetter + ": Type " + d.DriveType 
  IFB d.DriveType = 1 THEN
    PRINT "found " + d.path
    dim path = fso.buildPath(fso.buildPath(fso.buildPath(d.path, "DCIM"), "100__TSB"), "FA000001.JPG")
    PRINT "path " + path
    IFB fso.FileExists(path) THEN
      PRINT "file found"
      // 制御用画像のプロテクト判定
      dim file = fso.GetFile(path)
      IFB file.attributes AND $1 = $1 THEN
        // プロテクトON＝無線OFF
        SELECT SLCTBOX( SLCT_BTN, 0, "無線はOFFのようです", "ONにする", "OFFのまま(再設定)")
          CASE SLCT_1
            file.attributes = file.attributes XOR $1
            BALLOON("Flash Airの無線をONにしました", 0, 20, 20, 24, "MS ゴシック", $00FF00, $FFFFFF)
            SLEEP(3)
            BALLOON()
            PRINT "Wi-Fi ON"
          CASE SLCT_2
            // いったんONにしてOFFにし直す
            file.attributes = file.attributes XOR $1
            SLEEP(1)
            file.attributes = file.attributes OR $1
            PRINT "Wi-Fi Reset"
        SELEND
      ELSE
        // プロテクトOFF＝無線ON
        SELECT SLCTBOX( SLCT_BTN, 0, "無線はONのようです", "OFFにする", "ONのまま(再設定)")
          CASE SLCT_1
            file.attributes = file.attributes OR $1
            BALLOON("Flash Airの無線をOFFにしました", 0, 20, 20, 24, "MS ゴシック", $00FF00, $FFFFFF)
            SLEEP(3)
            BALLOON()
            PRINT "Wi-Fi OFF"
          CASE SLCT_2
            // いったんOFFにしてONにし直す
            file.attributes = file.attributes OR $1
            SLEEP(1)
            file.attributes = file.attributes XOR $1
            PRINT "Wi-Fi Reset"
        SELEND
      ENDIF
      // FlashAir二枚差しには非対応です
      EXIT
    ELSE
      PRINT "file not found"
    ENDIF
  ENDIF
next

Flash Air에 연결된 PC에서 이 스크립트를 실행하면 현재 무선 LAN 설정에 따라'무선이 켜진 것 같다'또는'무선이 꺼진 것 같다'는 대화 상자가 표시된다(자료를 읽으면 상태에 따라 이 설정이 일치하지 않을 수 있기 때문인 것 같다).

여기서 버튼을 선택한 후 컨트롤 이미지에 대한 읽기 전용 설정을 전환하면 무선 LAN의 상태가 변경됩니다(상태 재설정을 위해 현재 상태와 동일한 상태를 선택하더라도 읽기 전용 설정으로 전환).
어쨌든 이렇게 되면 PDF, 엑셀 표 따위는 PC에서 간단하게 공개할 수 있다.다른 용도가 있는 것 같아서 다시 해보고 싶어요.