1 소개

해석 등으로 ​​네트워크 패킷을 보존하고 싶은 경우, Windows OS에서는 Wireshark를 사용해 패킷 캡쳐 하는 것이 일반적이라고 생각합니다. 또한 매일 장시간 패킷 캡처하는 경우 PC가 갑자기 떨어지는 것도 생각하고 일정 시간에 자동 저장 해 주었으면합니다.
그 배치 파일을 작성했으므로 공유합니다.
※Wireshark의 GUI에서도 할 수 있습니다

2하고 싶은 일

· Wireshark를 사용하고 싶습니다.
· 일정 시간에 패킷을 저장하고 싶습니다.
· 매일 패킷을 폴더로 나누고 싶습니다.
※매일 배치를 실행, 종료하는 전제
· 배치 파일에서 실행하고 싶습니다.

3 동작 확인 환경

Wiondows 10
Wireshark 버전 2.0.5

4 배치 파일

auto_save_packet.bat

@echo off
@Rem 保存するフォルダを指定する
Set BASE_DIR=C:\packets\

@Rem BASE_DIRで指定したフォルダの下で日付のフォルダを作成する
Set TODAY=%DATE:~0,4%%DATE:~5,2%%DATE:~8,2%
Set FILE_DIR=%BASE_DIR%%TODAY%
Mkdir %FILE_DIR%

@Rem ネットワークインターフェイスを表示する
@echo ネットワークインターフェイス一覧
"C:\Program Files\Wireshark\tshark.exe" -D

@Rem ネットワークインターフェイスを入力する
set /p interface_id="パケットをキャプチャしたいネットワークインターフェイスを入力してください："

@Rem パケットの保存間隔を入力する
set /p time_duration="保存間隔(分)："
set /a "time_duration *= 60"

@echo Wiresharkでパケットを保存します。終了させたい場合はCtrl+Cを押してください。
"C:\Program Files\Wireshark\dumpcap.exe" -i %interface_id% -b duration:%time_duration% -w %FILE_DIR%\packet.pcapng

5 해설

저장 폴더를 지정합니다. 원하는 폴더를 지정합니다.

Set BASE_DIR=C:\packets\

지정한 저장 폴더에 날짜 이름으로 폴더를 만듭니다.

Set TODAY=%DATE:~0,4%%DATE:~5,2%%DATE:~8,2%
Set FILE_DIR=%BASE_DIR%%TODAY%
Mkdir %FILE_DIR%

네트워크 인터페이스 번호를 표시합니다. Wireshrak가 설치된 폴더에 있는 tshark.exe를 지정합니다. -D 옵션으로 인터페이스 번호를 표시할 수 있습니다.

"C:\Program Files\Wireshark\tshark.exe" -D

패킷 캡처하려는 네트워크 인터페이스의 번호와 패킷의 저장 간격 (분)을 입력합니다. 나중에 설명하지만 dumpcap.exe는 초 간격으로 지정되므로 분에서 초로 변환합니다.

@Rem ネットワークインターフェイスを入力する
set /p interface_id="パケットをキャプチャしたいネットワークインターフェイス番号を入力してください："

@Rem パケットの保存間隔を入力する
set /p time_duration="保存間隔(分)："
set /a "time_duration *= 60"

Wireshrak이 설치된 폴더에 있는 dumpcap.exe를 지정합니다.

"C:\Program Files\Wireshark\dumpcap.exe" -i %interface_id% -b duration:%time_duration% -w %FILE_DIR%\packet.pcapng

각 옵션에 대한 설명은 다음과 같습니다.


옵션
설명


-i
네트워크 인터페이스 번호 지정

-b duration
저장 간격(초)

-w
캡처 결과를 파일에 저장

6 실행 결과

명령 프롬프트의 출력은 다음과 같습니다.


패킷은 지정된 폴더 아래에 자동으로 저장됩니다. 패킷의 파일명에는 자동으로 일련 번호가 흔들립니다.

7 참고 사이트