집 PC의 WiFi가 끊어진 채로 되므로 자동으로 소생하는 ​​reWiFi.bat를 쓴 이야기입니다.

발단

아침, PC를 체크해 전원은 그대로 해 출근.
밤, 돌아오면 Wifi가 끊어져 연결되지 않는 채로 되어 있다.
라는 것이 최근 일어나고 있어 곤란하고 있었습니다.

케이블에 문제가 있을까 생각 본체에 Wifi 어댑터를 직접 찔러 모습을 보면, 그래도 연결되지 않게 된다.
Wifi를 한 번 무효화하고 다시 활성화하면 연결이 가능하다.

그래서 정기적으로 접속 상태를 감시하고, 끊어지면 회복시키는 bat 파일을 썼습니다.

방법

네트워크 인터페이스를 한 번 비활성화하고 다시 활성화합니다.

reWiFi.bat 파일

reWifi.bat

@echo off
rem チェック時間間隔を設定する(sec)
set interval=60

rem インターフェース名を設定 *netsh interface show interfaceで調べる
set "interfaceName=Wi-Fi"

rem 場所の移動する
cd /d "%~dp0"

rem 現在の状態を表示 
netsh interface show interface "%interfaceName%"

:checking
echo [%date% %time%] Checking %interfaceName%...
netsh interface show interface %interfaceName% | find "接続状態:             接続" > nul
if ERRORLEVEL 1 goto notconnection

rem 時間をおいてループします
timeout /t %interval% > nul
goto checking


:notconnection
echo [%date% %time%] %interfaceName%は切断されているようです。回復処理を開始します。

rem ログに日時を保存
echo %date% %time%,disconnect! %interfaceName%>> log_reWiFi.txt

echo [%date% %time%] %interfaceName% を無効化して待機します。
netsh interface set interface "%interfaceName%" disable > nul
timeout /t 10 > nul
echo [%date% %time%] %interfaceName% を再起動します。
netsh interface set interface "%interfaceName%" enable > nul
timeout /t 20
goto checking

pause

사용상의 주의

관리자 권한

동작에는 관리자 권한이 필요합니다.
右クリック > 管理者として実行.bat 파일 바로 가기를 만들고,プロパティ > ショートカットタブ > 詳細設定 부터管理者として実行(R) 에 체크를 둡니다.
더블 클릭으로 시작할 때 이 바로 가기에서 하면 편리합니다.

감시 시간

우선 60초로 하고 있습니다만, 300초(5분)라든지라도 좋을지도 모릅니다.
원하는대로 변경하십시오.

인터페이스 이름

우리 환경에서는 Wi-Fi라는 이름이었습니다. 환경에 맞게 변경하십시오.

C:\WINDOWS\system32>netsh interface show interface

Admin State    State          Type             Interface Name
-------------------------------------------------------------------------
有効             切断             専用               イーサネット
有効             切断             専用               イーサネット 2
有効             接続             専用               Wi-Fi

명령은 이런 식으로 Interface Name으로옵니다.

기타 정기 실행 방법

타이머 부분을 삭제하고, bat 파일을 태스크 스케줄러에 등록해 정기 실행하는,라든지라도 좋다고 생각합니다.

마지막 pause 필요 없어?

뭔가 넣어 두고 싶어지는군요 ... 에러 때 바로 윈도우 사라 버리고.

참고문헌

참고로 했습니다. 감사합니다!

wifi를 비활성화하고 활성화하는 bat|14로 고
htp : // bg. 14에. 네 t/2016/02/레보오토후후바 t. HTML
핵심 부분.

배치 파일을 항상 "관리자로 실행"하는 방법 - Windows - Project Group
htps //w w. p 로지ぇ ctg 납 p. 인후 / 치 ps / 우동 ws / 코 m_0092. HTML
바로 가기를 만들어 그곳에서 설정해 두는 방법.

Windows 배치 파일에서 ping 응답의 차이로 동작을 바꾼다 – OSAKANA TARO 메모장
htps : // bg. 오사카나. 네 t/아 r ゔぇ s/5429
처음에는 ping을 보고 판단하는 녀석을 쓰고 있었지만 인터페이스의 온 오프로 변경.

애초에 왜 자를 수 있니?

모르겠어... 아무것도...