일괄 처리 파일로 프린터 설치

자신의 메모입니다.
작은 회사라든지 여러 PC에 설치할 때 사용하고 있습니다.

대응 환경

WindowsXP ~ Windows10

32 or 64bit

절차

1. 프린터 드라이버 준비
2. 필요한 정보 찾기
3. 배치 파일을 만듭니다!

1. 프린터 드라이버 준비

1. 프린터 드라이버를 제조업체 사이트에서 다운로드합니다.
2. 다운로드한 파일을 적절한 위치에 저장합니다.

2. 필요한 정보 찾기

1. 파일에서 .inf 파일을 찾습니다.

※리코라면 이런 녀석

2. 파일을 열고 프린터 이름 찾기

※리코라면 이런 녀석으로, 이것의 「RICOH MP C4504 JPN RPCS」라고 하는 것이 프린터명
이 경우는 5 종류의 프린터에 대응하고 있는 것 같다?

3. 배치 파일을 만듭니다!

1. 배치 파일에 정보를 적용하여 준비 완료

※32bit판과 64bit판이 별도 드라이버라면, 각각의 파일을 준비한다.

「call :setup~」의 행을 프린터의 수만큼 늘어놓으면 엔터 1발로 전부 사용할 수 있게 된다! 해야. . . .

printer_install.bat

@echo off

call :checkWinVer
call :setup <プリンタに割り当てたIPアドレス> "<Windowsに設定するプリンタ名>" "<みつけたプリンタ名前>" "<32bitのINFファイルパス>" "<64bitのINFファイルパス>"
exit

:checkWinVer
VER | find "XP" > nul
IF not errorlevel 1 SET WIN_VER="Windows XP"
VER | find "Version 5.2." > nul
IF not errorlevel 1 SET WIN_VER="Windows XP"
VER | find "Version 6.0." > nul
IF not errorlevel 1 SET WIN_VER="Windows 2008"
VER | find "Version 6.1." > nul
IF not errorlevel 1 SET WIN_VER="Windows 7"
VER | find "Version 6.2." > nul
IF not errorlevel 1 SET WIN_VER="Windows 8"
VER | find "Version 10.0." > nul
IF not errorlevel 1 SET WIN_VER="Windows 10"
exit /b

:setup
REM #######  設定  #######
set PRT_IP=%1
set PRT_NAME=%2
set PRT_DV_NAME=%3
set PRT_DV_PATH_32=%4
set PRT_DV_PATH_64=%5
REM #######  処理  #######

IF EXIST %SYSTEMROOT%\System32\prnport.vbs (
set PRNPORT=%SYSTEMROOT%\System32\prnport.vbs
)
IF EXIST %SYSTEMROOT%\System32\Printing_Admin_Scripts\ja-JP\prnport.vbs (
set PRNPORT=%SYSTEMROOT%\System32\Printing_Admin_Scripts\ja-JP\prnport.vbs
)

if "%PROCESSOR_ARCHITECTURE%" EQU "x86" SET PRT_DV_PATH=%PRT_DV_PATH_32%
if "%PROCESSOR_ARCHITECTURE%" NEQ "x86" SET PRT_DV_PATH=%PRT_DV_PATH_64%
cd %SYSTEMROOT%\System32\Printing_Admin_Scripts\ja-JP
cscript %PRNPORT% -a -r IP_%PRT_IP% -h %PRT_IP% -o raw -n 9100
rundll32.exe printui.dll,PrintUIEntry /if /u /f %PRT_DV_PATH% /v %WIN_VER% /m %PRT_DV_NAME% /r IP_%PRT_IP% /b %PRT_NAME%
exit /b

이상한 곳 없을까. . . . . .