Perl TCP 클라이언트/서버 샘플 코드

이 게시물은 TCP 소켓을 사용하여 간단한 Perl 클라이언트/서버를 구현하는 방법을 설명합니다 🎉

코어 모듈인 IO::Socket::INET을 사용합니다(설치할 필요 없음). 핵심 모듈인지 어떻게 알 수 있습니까? list of core modules in perldoc을 확인하거나 간단히 corelist를 사용하십시오.

$ corelist IO::Socket::INET

Data for 2019-05-22
IO::Socket::INET was first released with perl v5.6.0

기다리지 않고 Perl TCP 클라이언트 구현으로 넘어갑시다👍

펄 TCP 클라이언트

3초마다 메시지("japh - "+ 클라이언트 타임스탬프 포함)를 보내고 신호(Control-C)에서 중지하는 매우 간단한 클라이언트입니다.

대상은 localhost(데모를 위해 동일한 컴퓨터에서 클라이언트와 서버를 실행 중입니다)이지만 완전히 다른 IP 또는 호스트 이름일 수 있습니다(분명히... 😀).

#!/usr/bin/env perl

use strict;
use warnings;

use IO::Socket::INET;
# auto-flush on socket
$| = 1;

my $continue = 1;
$SIG{INT} = sub { $continue = 0 };


while ($continue) {
    my $timestamp = localtime(time);
    my $msg = "japh - $timestamp";

    # Create a connecting socket
    my $socket = new IO::Socket::INET (
        PeerHost => 'localhost',
        PeerPort => '7777',
        Proto => 'tcp',
    );

    if($socket) {
        my $size = $socket->send($msg);
        print "Sent!\n";
        $socket->close();
    }

    sleep 3;
}

클라이언트 시작:

$ perl client.pl

클라이언트는 데이터를 보낸 다음 3초를 기다린 다음 다시 데이터를 보내고 대기하고 반복해서...

서버를 실행하자마자 클라이언트 라이브 실행은 다음과 같이 표시됩니다.


서버를 사용할 수 없는 경우 문제가 되지 않습니다. 클라이언트는 계속 활성 상태를 유지하고 서버가 시작될 때까지 아무에게도 전송하지 않습니다.

펄 TCP 서버

서버는 동일하게 보이지만 $socket 생성자 및 accept() 단계에 대한 매개변수가 더 많아 조금 더 복잡합니다.

#!/usr/bin/env perl

use strict;
use warnings;

use IO::Socket::INET;
# auto-flush on socket
$| = 1;


# Creating a listening socket
my $socket = new IO::Socket::INET (
    LocalHost => '0.0.0.0',
    LocalPort => '7777',
    Proto => 'tcp',
    Listen => 5,
    Reuse => 1
);
die "Cannot create socket $!\n" unless $socket;

$SIG{INT} = sub { $socket->close(); exit 0; };

while(1) {
    my $client_socket = $socket->accept();

    # Get information about a newly connected client
    my $client_address = $client_socket->peerhost();

    # Read up to 1024 characters from the connected client
    my $data = "";
    $client_socket->recv($data, 1024);
    print "$client_address - $data\n";
}

$socket->accept()는 차단 중이며 클라이언트가 연결을 시작하면 차단이 해제됩니다(클라이언트 측의 new IO::Socket::INET).

서버는 메시지( $msg )뿐만 아니라 IP 주소( $client_address 방법을 통한 peerhost() )도 검색합니다. 영원히 듣고 있으며 여러 클라이언트를 처리할 수 있습니다.

실행 중인 서버의 데모는 다음과 같습니다.


이제 도구 상자에 이러한 샘플 코드가 있으므로 사용자 지정 간단한 소형 클라이언트/서버 또는 매우 기본적인 모니터링 소프트웨어를 구현할 준비가 된 것입니다! 😁 💪