Google 스프레드시트의 시작/종료 날짜 사이에 날짜 채우기 및 필터링

시작 날짜와 종료 날짜 사이의 모든 날짜로 열을 채워야 했던 적이 있습니까? 특정 날짜를 무시해야 하는 경우 어떻게 해야 합니까? 금요일 데이트만 원한다면? Google 스프레드시트에서 방법을 알아봅시다!

스프레드시트 설정

다음 열을 만듭니다.

시작 날짜

종료 날짜

모든 날짜

무시된 날짜

필터링된 날짜

금요일

연속 번호

날짜가 실제로 내부적으로 숫자로 표시된다는 사실을 알고 계셨습니까? SEQUENCE 함수를 사용하여 날짜를 나타내는 일련의 숫자를 만들 수 있습니다. 행, 열 수 및 시작 값을 제공합니다.

행 수는 종료 날짜(B2)에서 시작 날짜(A2)를 뺀 값에 1을 더한 값입니다. 1을 더하지 않으면 종료 날짜가 포함되지 않습니다. 우리는 1개의 열만 원하기 때문에 열의 수는 1입니다. 시작 값은 시작 날짜(A2)입니다.

C2 셀에 다음 수식을 추가합니다.

=SEQUENCE(B2-A2+1, 1, A2)

이제 시작 날짜와 종료 날짜 사이의 모든 날짜를 나타내는 숫자 목록이 생겼습니다(시작 날짜와 종료 날짜 포함). 그러나 우리는 날짜를 나타내는 숫자가 아닌 실제 날짜를 원합니다.

숫자를 날짜로 변환

숫자를 날짜로 변환하려면 TO_DATE 함수를 사용할 수 있습니다. 숫자를 입력하면 날짜로 변환됩니다. C2 셀의 수식을 다음과 같이 업데이트합니다.

=TO_DATE(SEQUENCE(B2-A2+1, 1, A2))

무슨 일이에요? 이제 날짜가 하나만 나타납니까? TO_DATE 수식은 숫자 시퀀스의 첫 번째 값에만 적용되었습니다. 시퀀스의 모든 숫자에 대해 그렇게 하고 싶습니다. ARRAYFORMULA 함수가 도움이 될 수 있습니다. C2 셀의 수식을 다음과 같이 업데이트합니다.

=ARRAYFORMULA(TO_DATE(SEQUENCE(B2-A2+1, 1, A2)))

대박! 이제 시작일과 종료일 사이의 모든 날짜가 있습니다! 시작/종료 날짜를 변경하고 날짜 목록도 변경되는 것을 확인하세요!

참고: 여전히 날짜 대신 숫자가 표시되는 경우 C열을 선택하고 형식 > 숫자 > 날짜로 이동합니다.

참조 오류 방지

수식은 참조하는 셀에 값이 있을 때 잘 작동합니다. 시작일 또는 종료일을 아직 정의하지 않은 경우 어떻게 합니까? 그러면 오류가 표시됩니다. 우리는 그것을 쉽게 청소할 수 있습니다.

셀 C2에서 수식을 IFERROR 함수로 래핑하여 수식을 업데이트합니다. 오류 값이 아니면 첫 번째 인수를 반환하고, 그렇지 않으면 두 번째 인수로 정의한 것을 반환하거나 두 번째 인수가 제공되지 않으면 공백을 반환합니다.

=IFERROR(ARRAYFORMULA(TO_DATE(SEQUENCE(B2-A2+1, 1, A2))))

시작 날짜 또는 종료 날짜 값을 제거하면 해당 값을 참조하는 다른 셀에 오류가 표시되지 않습니다.

날짜 필터링

무시한 날짜 열(D)에서 몇 가지 날짜를 정의합니다. 필터링된 날짜 열(E)에서 무시한 날짜 열(D)에 정의된 날짜를 제외하고 모든 날짜 열(C)의 모든 날짜를 나열하려고 합니다.

FILTER 함수를 사용하여 무시한 날짜 범위를 기준으로 모든 날짜 범위를 필터링해 보겠습니다. NOT 및 COUNTIF 함수는 범위를 비교할 때 참/거짓 조건을 제공하는 데 도움이 됩니다. 셀 E2에 다음 수식을 입력합니다.

=FILTER(C2:C, NOT(COUNTIF(D2:D, C2:C)))

금요일 날짜

요일에 특정한 날짜를 원하면 어떻게 합니까? QUERY 함수와 함께 구문과 유사한 SQL을 사용하여 데이터를 쿼리할 수 있습니다. F2 셀에 다음 수식을 입력합니다.

=QUERY(E2:E, "SELECT E WHERE dayOfWeek(E) = 6")

필터링된 날짜 열(E)이 데이터 소스로 사용되고 있습니다. E 열을 선택하고 요일이 6인 날짜(일요일은 1, 월요일은 2 등)를 선택합니다.


저희 웹사이트 https://nightwolf.dev를 방문하고 Facebook 및 !