[Excel] 두 번째 이후의 파일 (북)을 열면 창이 어긋나므로 고정하는 방법

개요

Excel을 열고있는 상태에서 또 다른 통합 문서를 열려고하면 ...



창이 오른쪽 아래로 조금 어긋난다! ! (이라~~) 되지 않습니까?
그래서 창의 표시 위치를 고정하는 방법입니다.

방법

개인용 매크로북 열기(추가)

먼저 개발 탭 → Visual Basic에서 VBE를 엽니다.
그런 다음 개인용 매크로북을 엽니다.
(프로젝트에서 “VBAProject(PERSONAL.XLSB)” → “ThisWorkbook” 열기)

PERSONAL.XLSB가 없는 경우

개발 탭 → 매크로 기록을 선택하여 적절한 이름으로 매크로를 기록합니다.
이 때 매크로의 저장처를 「개인용 매크로 북」으로 설정합니다.
이제 PERSONAL.XLSB가 생성됩니다.

매크로 추가

PERSONAL.XLSB의 ThisWorkbook에 다음과 같이 코드를 추가합니다.

Public WithEvents xlAPP As Application

' PERSONAL.XLSBのオープンイベント
Private Sub Workbook_Open()
    ' 他のブックのイベントも受け取れるようにする
    Set xlAPP = Application
End Sub

' 新規作成時のイベント
Private Sub xlAPP_NewWorkbook(ByVal Wb As Excel.Workbook)
    WindowReset
End Sub

' 既存ブックのオープンイベント
Private Sub xlAPP_WorkbookOpen(ByVal Wb As Excel.Workbook)
    ' 自身のオープンイベントは読み捨てる
    If Wb.Name = "PERSONAL.XLSB" Then
       Exit Sub
    End If

    WindowReset
End Sub

' Windowの初期位置を指定する
Private Sub WindowReset()
    Application.Top = 10
    Application.Left = 50
    Application.Width = 1280
    Application.Height = 760
End Sub

이것으로 북을 열었을 때나 신규 작성시에 윈도우를 고정 위치·사이즈로 표시할 수 있습니다.
(WindowReset의 내용은 적당히 기호로 설정해 주세요)

주의사항

VBA이므로 매크로가 무효화되어 있는 파일(웹으로부터 다운로드한 직후에 보호 뷰가 유효하게 되어 있는 등)에서는 기능하지 않습니다.