UltraEdit Win32ASM 실험 환경 구축

@echo off

rem Simply Complie, Build and Execute Win32ASM programs.

rem Author: t0nsha<liaodunxia{at}gmail.com>, Update@20080526

set filename="%~n1"

if not exist %filename%.asm (

	echo Error! The asm source file: "%filename:"=%.asm" does not exist!

	echo Usage: %~n0 filename[.asm]

	pause

	goto :eof

)

if not exist "D:/masm32/bin/ML.exe" (

	echo Error! Can't find "D:/masm32/bin/ML.exe" !

	echo Please confirm you've already installed masm32v9r at the root of the d:/

	pause

	goto :eof

)

set include=D:/masm32/include;%include%

set lib=D:/masm32/lib;%lib%

set path=D:/masm32/bin;%PATH%

set mlOption=/c /coff /Cp /Zi /nologo

set linkOption=/SUBSYSTEM:WINDOWS /DEBUG /DEBUGTYPE:CV /NOLOGO

set linkfile=%filename%.obj



call :Clean %filename% exe pdb

ml %mlOption% %filename%.asm

if exist %filename%.rc (

	rc %filename%.rc

	set linkfile=%linkfile% %filename%.res

)

rem To share ".data?" section, please add: /section:.bss,S

if exist %filename%.def set linkOption=%linkOption% /DLL /DEF:%filename%.def

link %linkOption% %linkfile%

rem Ext INFO: http://support.microsoft.com/default.aspx?scid=kb;en-us;Q132340

call :Clean %filename% obj res ilk exp

if exist %filename%.exe start /b cmd /c %filename%.exe

echo on & goto :eof



:Clean

if "%2"=="" goto :CleanEnd

if exist %filename%.%2 del %filename%.%2

shift

goto Clean

:CleanEnd