Zoom을 음소거하는 물리적 버튼 만들기

Zoom의 마이크 음소거 전환이 귀찮아 & 지금 음소거인지 불안해지기 때문에,
물리적으로 전환 가능하고, 외형에도 알기 쉬운 버튼을 ATOM Matrix로 만들었습니다.

※구조는 단지의 쇼트 컷 키이므로, 바꿀 수 있을까 & 정말로 지금 뮤트인지는 보증할 수 없습니다

할 수있는 것

출처

Arduino

#include "M5Atom.h"
#include <FastLED.h>
#include <BleKeyboard.h>

#define NUM_LEDS 25

#define LED_PIN 27

CRGB leds[NUM_LEDS];
BleKeyboard bleKeyboard("MUTE BUTTON");

const uint8_t cmd[] = {KEY_LEFT_SHIFT, KEY_RIGHT_GUI, 'a'};
bool isMute = true;

void sendCmd(){
    int length = sizeof cmd / sizeof cmd[0];
    for (int index = 0; index < length; index++) {
        bleKeyboard.press(cmd[index]);
    }
    delay(100);
    bleKeyboard.releaseAll();
}

void setColor(CRGB c){
    CRGB converted = CRGB(c.g, c.r, c.b);
    for (int index = 0; index < NUM_LEDS; index++){
        leds[index] = converted;
    }
    FastLED.show();
}

void setup() {
    M5.begin(true, false, true);
    bleKeyboard.begin();

    FastLED.addLeds<WS2812, LED_PIN>(leds, NUM_LEDS);
    FastLED.setBrightness(15);
}

void loop() {
    M5.update();
    if(bleKeyboard.isConnected()){
        if(M5.Btn.wasPressed()){
            sendCmd();
            isMute = !isMute;
        }
        setColor((isMute) ? CRGB::Red : CRGB::Lime);
    }else{
        setColor(CRGB::Black);
    }
    delay(10);
}

Bluetooth 키보드로 인식시키기 위해 ESP32-BLE-Keyboard
LED 제어에 FastLED을 사용합니다.
각각 설치하십시오.

버튼(전면 LED 매트릭스)을 누를 때마다 ⌘ + ⇧ + A를 입력하여 Zoom의 마이크 음소거를 토글합니다.

※Zoom을 표시하고 있지 않을 때에도 전환하기 위해서는 Zoom측에서 글로벌 단축키를 유효하게 할 필요가 있습니다.


USB로 연결하는 데 BLE 경유가 슬픈 ... 기술력이 부족했습니다.
눈치채는 것, 신경이 쓰인 것을 코멘트해 주시면 격려가 됩니다.